Assembly Language Tutorial

 
 
 

Instructions

Input - Output Instructions

Display a character Read a character and display it on new line Display string Read digit, compute and display sum w/o variable Read digit, display difference w/o variable Read digit, compute, display sum using variable Read digit, display difference using variable Convert lower case letter in to upper case Read character, display in new line - user prompt Read 1st, middle, last initial - down left margin Read one hex digit, display next line in decimal Display 10*10 solid box asterisk - INT 21H and 9H Read 3 char show in middle of 11*11 box, beep comp

Flow Control Instructions

Print ASCII characters Print counting from 0 to 9 Print upper case letters from A to Z Print lower case letters from a to z in reverse Read letter print if it is \'?\' - simulation of if Read char print smallest - simulation of if-else Positive, negative num- simulation of switch-case Print upper case char - simulation of if-else then Simulation of if-else then structure Print ASCII characters - for loop simulation Print upper case A to Z - while loop simulation Print upper case A to Z - Do while loop simulation Read letters display in next line in alpha order Display digit in next line if fail prompt message Read hex digit display on next line in decimal Display capital letter in string alphabetically Show longest sequence consecutive alphabetically

Logic - Shift - Rotate Instructions

Convert upper to lower case - OR logic instruction Convert lower to upper - AND logic instruction Display even or odd number - TEST instruction Multiply content of AL by 8 - SHL instruction Divide content of AL by 4 - SHR instruction Store binary- BX,count bit value 1 w/o changing BX Read binary num, reverse its bit pattern Read binary number store in BX and display Read char- show ASCII in binary- 1 bit in ASC code Read char print ASCII in HEX till- carriage return Read HEX number and print in binary next line Read binary number and print in HEX next line Read 2 binary number and print its sum in binary Read 2 unsigned HEX num and print their sum Read string of decimal digit print sum in HEX Read str of char ter by CR show reverse order Read character using procedure goto next line Binary form & reverse bit of num - procedures Product by ADD, SHIFT instruction - procedure Display text with letters in each word reversed Validate expression READ store bin num in AX, RANDOM, WRITE

Multiplication - Division Instructions

Print factorial in binary form - MUL instruction Print num decimal form - DIV, OUTDEC proc Print factorial in decimal form - MUL, DIV instru Print num next line - proc for DECIMAL i/o Proc INDEC and OUTDEC, handle BackSpace key Proc INDEC and OUTDEC - files - INCLUDE instru Print factorial in dec form - MUL, DIV instruction Proc INDEC, OUTDEC - Handle OverFlow Read time in seconds display time HH:MM:SS Express - quarter, dime, nickel, pennie Read fraction form M/N print N decimal place GCD of two integers M and N

Arrays - Addressing Modes

Sum of array - sum in AX - Register Indirect Mode Initialize array with 0 using DUP instruction Enter an array of size 10 and display it Declare, initialize, print 2D array of size 5x5 Enter 2D array of 5x5 in row major order, print Print 3rd R x 4th C using Register Indirect Mode Display reversing array contents using STACK Reverse content of array - Register Indirect Mode Sort array using Bubble Sort method Sort an array using Select Sort method Print 2D array of size 4x5 in row major order Print 2D array of size 4x5 in column major order 2D arr clear 3rd row 4th column - Based Index Mode Compute class average on each exam Print name each student, average of 4 exams Insert single characters into array - it is sorted

String Instructions

Copy string into another using MOVSB, REP Read string, stores in variable using STOSB Display string using instruction LODSB Store display str - proc READ_STR, DISP_STR Count no of vowels constants - SCASB, REPNE

General Programs

Get and display the current system time
 
 
 .MODEL SMALL
 .STACK 100H

 .DATA
   PROMPT_1  DB  \'Enter a string : $\'
   PROMPT_2  DB  0DH,0AH,\'No. of Vowels = $\'
   PROMPT_3  DB  0DH,0AH,\'No. of Consonants = $\'

   STRING        DB  50 DUP (?)   
   C_VOWELS      DB  \'AEIOU\'
   S_VOWELS      DB  \'aeiou\'
   C_CONSONANTS  DB  \'BCDFGHJKLMNPQRSTVWXYZ\'
   S_CONSONANTS  DB  \'bcdfghjklmnpqrstvwxyz\'

 .CODE
   MAIN PROC
     MOV AX, @DATA                ; initialize DS and ES
     MOV DS, AX
     MOV ES, AX

     LEA DX, PROMPT_1             ; load and display the string PROMPT_1
     MOV AH, 9
     INT 21H

     LEA DI, STRING               ; set DI=offset address of variable STRING

     CALL READ_STR                ; call the procedure READ_STR

     XOR DX, DX                   ; clear DX
     LEA SI, STRING               ; set SI=offset address of variable STRING

     OR BX, BX                    ; check BX for 0
     JE @EXIT                     ; jump to label @EXIT if BX=0

     @COUNT:                      ; jump label
       LODSB                      ; set AL=DS:SI

       LEA DI, C_VOWELS           ; set DI=offset address of variable C_VOWELS
       MOV CX, 5                  ; set CX=5

       REPNE SCASB                ; check AL is capital vowel or not
       JE @INCREMENT_VOWELS       ; jump to label @INCREMENT_VOWELS if AL is
                                  ; capital vowel

       LEA DI, S_VOWELS           ; set DI=offset address of variable S_VOWELS
       MOV CX, 5                  ; set CX=5

       REPNE SCASB                ; check AL is small vowel or not
       JE @INCREMENT_VOWELS       ; jump to label @INCREMENT_VOWELS if AL is
                                  ; small vowel

       LEA DI, C_CONSONANTS       ; set DI=offset address of variable
                                  ; C_CONSONANTS
       MOV CX, 21                 ; set CX=21

       REPNE SCASB                ; check AL is capital consonant or not
       JE @INCREMENT_CONSONANTS   ; jump to label @INCREMENT_CONSONANTS if AL
                                  ; is capital consonant

       LEA DI, S_CONSONANTS       ;  set DI=offset address of variable
                                  ; S_CONSONANTS
       MOV CX, 21                 ; set CX=21

       REPNE SCASB                ; check AL is small consonant or not
       JE @INCREMENT_CONSONANTS   ; jump to label @INCREMENT_CONSONANTS if AL
                                  ; is small consonants

       JMP @NEXT                  ; otherwise, jump to label @NEXT

       @INCREMENT_VOWELS:         ; jump label
         INC DL                   ; increment DL
         JMP @NEXT                ; jump to label @NEXT

       @INCREMENT_CONSONANTS:     ; jump label
         INC DH                   ; increment DH

       @NEXT:                     ; jump label
         DEC BX                   ; decrement BX
         JNE @COUNT               ; jump to label @COUNT while BX!=0

       @EXIT:                     ; jump label

     MOV CX, DX                   ; set CX=DX

     LEA DX, PROMPT_2             ; load and display the string PROMPT_2
     MOV AH, 9                     
     INT 21H                       

     XOR AX, AX                   ; clear AX
     MOV AL, CL                   ; set AL=CL

     CALL OUTDEC                  ; call the procedure OUTDEC

     LEA DX, PROMPT_3             ; load and display the string PROMPT_3
     MOV AH, 9
     INT 21H

     XOR AX, AX                   ; clear AX
     MOV AL, CH                   ; set AL=CH

     CALL OUTDEC                  ; call the procedure OUTDEC

     MOV AH, 4CH                  ; return control to DOS
     INT 21H
   MAIN ENDP



 ;-------------------------  Procedure Definitions  ------------------------;




 ;-------------------------------  READ_STR  -------------------------------;


  READ_STR PROC
    ; this procedure will read a string from user and store it
    ; input : DI=offset address of the string variabel
    ; output : BX=number of characters read
    ;        : DI=offset address of the string variabel

    PUSH AX                       ; push AX onto the STACK
    PUSH DI                       ; push DI onto the STACK

    CLD                           ; clear direction flag
    XOR BX, BX                    ; clear BX

    @INPUT_LOOP:                  ; loop label
      MOV AH, 1                   ; set input function 
      INT 21H                     ; read a character

      CMP AL, 0DH                 ; compare AL with CR
      JE @END_INPUT               ; jump to label @END_INPUT if AL=CR

      CMP AL, 08H                 ; compare AL with 08H
      JNE @NOT_BACKSPACE          ; jump to label @NOT_BACKSPACE if AL!=08H

      CMP BX, 0                   ; compare BX with 0
      JE @INPUT_ERROR             ; jump to label @INPUT_ERROR if BX=0

      MOV AH, 2                   ; set output function
      MOV DL, 20H                 ; set DL=20H
      INT 21H                     ; print a character

      MOV DL, 08H                 ; set DL=08H
      INT 21H                     ; print a character

      DEC BX                      ; set BX=BX-1
      DEC DI                      ; set DI=DI-1
      JMP @INPUT_LOOP             ; jump to label @INPUT_LOOP

      @INPUT_ERROR:               ; jump label
      MOV AH, 2                   ; set output function
      MOV DL, 07H                 ; set DL=07H
      INT 21H                     ; print a character

      MOV DL, 20H                 ; set DL=20H
      INT 21H                     ; print a character
      JMP @INPUT_LOOP             ; jump to label @INPUT_LOOP      

      @NOT_BACKSPACE:             ; jump label
      STOSB                       ; set ES:[DI]=AL
      INC BX                      ; set BX=BX+1
      JMP @INPUT_LOOP             ; jump to label @INPUT_LOOP

    @END_INPUT:                   ; jump label

    POP DI                        ; pop a value from STACK into DI
    POP AX                        ; pop a value from STACK into AX

    RET
  READ_STR ENDP


 ;--------------------------------  OUTDEC  --------------------------------;


 OUTDEC PROC
   ; this procedure will display a decimal number
   ; input : AX
   ; output : none

   PUSH BX                        ; push BX onto the STACK
   PUSH CX                        ; push CX onto the STACK
   PUSH DX                        ; push DX onto the STACK

   CMP AX, 0                      ; compare AX with 0
   JGE @START                     ; jump to label @START if AX>=0

   PUSH AX                        ; push AX onto the STACK

   MOV AH, 2                      ; set output function
   MOV DL, \"-\"                    ; set DL=\'-\'
   INT 21H                        ; print the character

   POP AX                         ; pop a value from STACK into AX

   NEG AX                         ; take 2\'s complement of AX

   @START:                        ; jump label

   XOR CX, CX                     ; clear CX
   MOV BX, 10                     ; set BX=10

   @OUTPUT:                       ; loop label
     XOR DX, DX                   ; clear DX
     DIV BX                       ; divide AX by BX
     PUSH DX                      ; push DX onto the STACK
     INC CX                       ; increment CX
     OR AX, AX                    ; take OR of Ax with AX
   JNE @OUTPUT                    ; jump to label @OUTPUT if ZF=0

   MOV AH, 2                      ; set output function

   @DISPLAY:                      ; loop label
     POP DX                       ; pop a value from STACK to DX
     OR DL, 30H                   ; convert decimal to ascii code
     INT 21H                      ; print a character
   LOOP @DISPLAY                  ; jump to label @DISPLAY if CX!=0

   POP DX                         ; pop a value from STACK into DX
   POP CX                         ; pop a value from STACK into CX
   POP BX                         ; pop a value from STACK into BX

   RET                            ; return control to the calling procedure
 OUTDEC ENDP





 END MAIN

    Related Post:
  1. Program that prompts the user to enter an 2D array of size 5x5 in row major order and print it.

  2. Program to print Upper Case Letters from A to Z

  3. PROGRAM TO CHECK GIVEN TWO VALUE ARE EQUAL OR NOT

  4. Program that will display a string using instruction LODSB.......

  5. PROGRAM TO CLEAR THE SCREEN AND MAKE BLUE FOREGROUND

  6. Procedure that prompts the user to read a decimal number in the range -32767 to +32767

  7. Program that will read a positive binary number and print its factorial in decimal form using MUL and DIV instructionsand use OUTDEC procedure........

  8. Program to compare two strings

  9. Program to read a letter in Lower case and print it after converting it in to Upper case letter..........

  10. Program of an array that prints its value before and after clearing the 3rd row and 4th column using based index mode

  11. Program to check whether the input string is palindrome or not

  12. PROGRAM TO CLEAR SCREEN

  13. Program to Print the Fibonacci series

  14. TO INPUT A HEX CHARACTER AND DISPLAY IT AS MANY TIMES AS THAT OF THE HEX CHARACTER

  15. Program that will read a binary number and print it on the next line in decimal form using DIV instruction and OUTDEC procedure.

  16. Program to search for numbers between 0-9, if found replace them with there corresponding special characters on the keyboard

  17. Program that will read and print a decimal number using procedures INDEC and OUTDEC. Place the procedures in separate files and use the INCLUDE.......

  18. Program to Calculate the average of n numbers

  19. Program to read a character and display it on next line using a procedure for goto next line...............

  20. PROGRAM TO WRITE A PROGRAM TO ADD TWO MEMORY LOCATIONS AND STORE THE RESULT IN THIRD MEMORY LOCATION