Assembly Language Tutorial

 
 
 

Instructions

Input - Output Instructions

Display a character Read a character and display it on new line Display string Read digit, compute and display sum w/o variable Read digit, display difference w/o variable Read digit, compute, display sum using variable Read digit, display difference using variable Convert lower case letter in to upper case Read character, display in new line - user prompt Read 1st, middle, last initial - down left margin Read one hex digit, display next line in decimal Display 10*10 solid box asterisk - INT 21H and 9H Read 3 char show in middle of 11*11 box, beep comp

Flow Control Instructions

Print ASCII characters Print counting from 0 to 9 Print upper case letters from A to Z Print lower case letters from a to z in reverse Read letter print if it is \'?\' - simulation of if Read char print smallest - simulation of if-else Positive, negative num- simulation of switch-case Print upper case char - simulation of if-else then Simulation of if-else then structure Print ASCII characters - for loop simulation Print upper case A to Z - while loop simulation Print upper case A to Z - Do while loop simulation Read letters display in next line in alpha order Display digit in next line if fail prompt message Read hex digit display on next line in decimal Display capital letter in string alphabetically Show longest sequence consecutive alphabetically

Logic - Shift - Rotate Instructions

Convert upper to lower case - OR logic instruction Convert lower to upper - AND logic instruction Display even or odd number - TEST instruction Multiply content of AL by 8 - SHL instruction Divide content of AL by 4 - SHR instruction Store binary- BX,count bit value 1 w/o changing BX Read binary num, reverse its bit pattern Read binary number store in BX and display Read char- show ASCII in binary- 1 bit in ASC code Read char print ASCII in HEX till- carriage return Read HEX number and print in binary next line Read binary number and print in HEX next line Read 2 binary number and print its sum in binary Read 2 unsigned HEX num and print their sum Read string of decimal digit print sum in HEX Read str of char ter by CR show reverse order Read character using procedure goto next line Binary form & reverse bit of num - procedures Product by ADD, SHIFT instruction - procedure Display text with letters in each word reversed Validate expression READ store bin num in AX, RANDOM, WRITE

Multiplication - Division Instructions

Print factorial in binary form - MUL instruction Print num decimal form - DIV, OUTDEC proc Print factorial in decimal form - MUL, DIV instru Print num next line - proc for DECIMAL i/o Proc INDEC and OUTDEC, handle BackSpace key Proc INDEC and OUTDEC - files - INCLUDE instru Print factorial in dec form - MUL, DIV instruction Proc INDEC, OUTDEC - Handle OverFlow Read time in seconds display time HH:MM:SS Express - quarter, dime, nickel, pennie Read fraction form M/N print N decimal place GCD of two integers M and N

Arrays - Addressing Modes

Sum of array - sum in AX - Register Indirect Mode Initialize array with 0 using DUP instruction Enter an array of size 10 and display it Declare, initialize, print 2D array of size 5x5 Enter 2D array of 5x5 in row major order, print Print 3rd R x 4th C using Register Indirect Mode Display reversing array contents using STACK Reverse content of array - Register Indirect Mode Sort array using Bubble Sort method Sort an array using Select Sort method Print 2D array of size 4x5 in row major order Print 2D array of size 4x5 in column major order 2D arr clear 3rd row 4th column - Based Index Mode Compute class average on each exam Print name each student, average of 4 exams Insert single characters into array - it is sorted

String Instructions

Copy string into another using MOVSB, REP Read string, stores in variable using STOSB Display string using instruction LODSB Store display str - proc READ_STR, DISP_STR Count no of vowels constants - SCASB, REPNE

General Programs

Get and display the current system time
 

Program of an array that prints its value before and after clearing the 3rd row and 4th column using based index mode

 
 .MODEL SMALL
 .STACK 100H

 .DATA
   PROMPT_1  DB  \'The contents of Array before clearing 3rd row and 4th column are : \',0DH,0AH,\'$\'
   PROMPT_2  DB  0DH,0AH,\'The contents of Array after clearing 3rd row and 4th column are : \',0DH,0AH,\'$\'

   ARRAY  DW  1,2,3,4,5,6,7
          DW  8,9,10,11,12,13,14
          DW  15,16,17,18,19,20,21
          DW  22,23,24,25,26,27,28
          DW  29,30,31,32,33,34,35
 .CODE
   MAIN PROC
     MOV AX, @DATA                ; initialize DS
     MOV DS, AX

     MOV BH, 5                    ; set BH=5
     MOV BL, 7                    ; set BL=7

     LEA DX, PROMPT_1             ; load and print the string PROMPT_1 
     MOV AH, 9
     INT 21H

     LEA SI, ARRAY                ; set SI=offset address of variable ARRAY

     CALL PRINT_2D_ARRAY          ; call the procedure PRINT_2D_ARRAY

     PUSH BX                      ; push BX onto the STACK

     MOV BX, 28                   ; set BX=28 : first element of 3rd row
     XOR SI, SI                   ; clear SI
     MOV CX, 7                    ; set CX=7 : size of row

     @CLEAR_ROW:                  ; loop label
       MOV ARRAY[BX][SI], 0       ; set ARRAY[BX][SI]=0
       ADD SI, 2                  ; set SI=SI+2 : next element of row
     LOOP @CLEAR_ROW              ; jump to label @CLEAR_ROW while CX!=0

     MOV BX, 6                    ; set BX=6 : first element of 4th column
     XOR SI, SI                   ; clear SI
     MOV CX, 5                    ; set CX=5 : size of column

     @CLEAR_COLUMN:               ; loop label
       MOV ARRAY[BX][SI], 0       ; set ARRAY[BX][SI]=0
       ADD SI, 14                 ; set SI=SI+14 : next element of column
     LOOP @CLEAR_COLUMN           ; jump to label @CLEAR_COLUMN while CX!=0

     POP BX                       ; pop a value from STACK into BX

     LEA DX, PROMPT_2             ; load and print the string PROMPT_2 
     MOV AH, 9
     INT 21H

     LEA SI, ARRAY                ; set SI=offset address of variable ARRAY

     CALL PRINT_2D_ARRAY          ; call the procedure PRINT_2D_ARRAY

     MOV AH, 4CH                  ; return control to DOS
     INT 21H
   MAIN ENDP



 ;-------------------------  Procedure Definitions  ------------------------;




 ;-----------------------------  PRINT_2D_ARRAY  ---------------------------;


  PRINT_2D_ARRAY PROC
    ; this procedure will print the given 2D array
    ; input : SI=offset address of the 2D array
    ;       : BH=number of rows
    ;       : BL=number of columns 
    ; output : none

   PUSH AX                        ; push BX onto the STACK
   PUSH CX                        ; push CX onto the STACK
   PUSH DX                        ; push DX onto the STACK
   PUSH SI                        ; push SI onto the STACK

   MOV CX, BX                     ; set CX=BX

   @OUTER_LOOP:                   ; loop label
     MOV CL, BL                   ; set CL=BL

     @INNER_LOOP:                 ; loop label
       MOV AH, 2                  ; set output function
       MOV DL, 20H                ; set DL=20H
       INT 21H                    ; print a character

       MOV AX, [SI]               ; set AX=[SI]

       CALL OUTDEC                ; call the procedure OUTDEC

       ADD SI, 2                  ; set SI=SI+2
       DEC CL                     ; set CL=CL-1
     JNZ @INNER_LOOP              ; jump to label @INNER_LOOP if CL!=0

     MOV AH, 2                    ; set output function
     MOV DL, 0DH                  ; set DL=0DH
     INT 21H                      ; print a character

     MOV DL, 0AH                  ; set DL=0AH
     INT 21H                      ; print a character

     DEC CH                       ; set CH=CH-1
   JNZ @OUTER_LOOP                ; jump to label @OUTER_LOOP if CX!=0

   POP SI                         ; pop a value from STACK into SI
   POP DX                         ; pop a value from STACK into DX
   POP CX                         ; pop a value from STACK into CX
   POP AX                         ; pop a value from STACK into AX

   RET
 PRINT_2D_ARRAY ENDP


 ;--------------------------------  OUTDEC  --------------------------------;


 OUTDEC PROC
   ; this procedure will display a decimal number
   ; input : AX
   ; output : none

   PUSH BX                        ; push BX onto the STACK
   PUSH CX                        ; push CX onto the STACK
   PUSH DX                        ; push DX onto the STACK

   XOR CX, CX                     ; clear CX
   MOV BX, 10                     ; set BX=10

   @OUTPUT:                       ; loop label
     XOR DX, DX                   ; clear DX
     DIV BX                       ; divide AX by BX
     PUSH DX                      ; push DX onto the STACK
     INC CX                       ; increment CX
     OR AX, AX                    ; take OR of Ax with AX
   JNE @OUTPUT                    ; jump to label @OUTPUT if ZF=0

   MOV AH, 2                      ; set output function

   @DISPLAY:                      ; loop label
     POP DX                       ; pop a value from STACK to DX
     OR DL, 30H                   ; convert decimal to ascii code
     INT 21H                      ; print a character
   LOOP @DISPLAY                  ; jump to label @DISPLAY if CX!=0

   POP DX                         ; pop a value from STACK into DX
   POP CX                         ; pop a value from STACK into CX
   POP BX                         ; pop a value from STACK into BX

   RET                            ; return control to the calling procedure
 OUTDEC ENDP





 END MAIN

    Related Post:
  1. PROGRAM TO GET STRING FROM KEYBOARD & PRINT IT
  2. Program to read a character and display it on next line using a procedure for goto next line...............
  3. Program to display a string
  4. Program to encrypt the given string
  5. Program display the ascii characters on the screen using BIOS interrupt (INT 10H)
  6. Program to Print a Color Border on the Screen
  7. Program to find the no. of occurrences of character \`c in the input string
  8. Program to evaluate a postfix expression
  9. Program to find whether the input number is divisible by n or not
  10. TO INPUT A HEX CHARACTER AND DISPLAY IT AS MANY TIMES AS THAT OF THE HEX CHARACTER
  11. Program to convert decimal number to binary
  12. Program that declares and initializes a 2D array of size 4x5 in row major order, and print it.
  13. Program to perform selection sort
  14. Program to Print the Fibonacci series
  15. Program that prompts a user to enter a line of text. On the next line, display the capital letter entered that comes first alphabetically......
  16. PROGRAM TO READ TODAYS DATE THROUGH KEYBOARD AND THEN DISPLAY THE CORRESPONDING DAY AND MONTH
  17. Program that read first, middle, and last initials of a persons name and display them down the left margin
  18. PROGRAM TO CLEAR SCREEN
  19. Program that declares and initialize a 2D array in row major order, and print the contents of the 3rd row and 4th column using Register Indirect mode
  20. Program to display a character